Copyright ©
Fred van den Bosch
Flow Bench Arduino
Flow Bench Arduino
De tekst op deze pagina is in het Nederlands. Dit omdat de gegevens over mijn flow bench al eerder op een Nederlandse site zijn verschenen.


Het meest logische om een flowmeter met een Arduino te bouwen leek mij een barometer-module. Na het overhandigen van een luttele VND 150.000 aan L  (
http://www.motor-forum.nl/forum/list_message/26792436#26792436 <http://www.motor-forum.nl/forum/list_message/26792436>) was ik de trotse eigenaar van een printplaatje van ca. 2*2 cm. met daarop een sensor en nog wat miniscule onderdeeltjes. Op internet vond ik de aansluitingsgegevens en een bijbehorend programma (sketch). Zie https://www.sparkfun.com/tutorials/253 . Vier kabeltjes gelegd tussen Arduino en module, het programma gekopieerd en in de Arduino gezet en voila, het zaakje werkte in n keer.

Ik heb allereerst de uitlezing wat aangepast. Hij geeft nu een getal in plaats van de luchtdruk. Hoe lager de luchtdruk, hoe hoger de waarde. Getest met de losse stofzuiger, de basis van de eenvoudige flow bench. Het uiteinde van de slang bij het module gehouden en de waarde vloog omhoog. Het werkte!

Vervolgens het barometer-module in een stukje pvc-pijp ingebouwd. Weer een test met de stofzuiger en een losse sonde. Het bleek dat het gat, waar het snoertje door naar binnen gaat, goed afgesloten moet worden, anders wordt de waarde nauwelijks hoger. Daarna ging het een stuk beter.

Ik verwacht dus dat het meten op mijn flow bench nu ook goed gaat -de basis daarvan is dezelfde stofzuiger- maar daar ben ik nog niet aan toegekomen. De ultieme test moet ik ook nog uitvoeren: met een paar sondes de flow op de inlaat van de motor meten. Zal ik binnenkort een keer proberen.

Omdat ik toch lekker bezig was heb ik ook maar meteen het programma wat aangepast. Ik ben nu niet meer afhankelijk van een computer voor de uitlezing , maar zie de waardes rechtstreeks op een display (zie de foto). Ook zijn wat overbodige regels -voor zover herkenbaar- verwijderd.

Verder heb ik de startwaarde van de flow aangepast. Dat is nu de luchtdruk op het moment van opstarten. Op die manier begint mijn meting altijd ongeveer op 0. Ongeveer vanwege het altijd wel iets schommelen van de luchtdruk. Echt noodzakelijk is het niet: je meet de verschillen en niet de absolute waarde. Net als bij de watermanometer. Maar het staat wel netjes op die manier.

Op termijn wil ik het geheel zelfstandig maken dus de Arduino met uitlezing en voeding in een apart kastje bouwen. Een aantal onderdelen zijn inmiddels aangeschaft.

Op de foto is de huidige testopstelling te zien. Van onder naar boven:
- Een testboard met het twee-regelig display
- De Arduino
- De pvc-pijp met daarin het barometermodule. Vanaf de bovenkant loopt de slang met probe.
























Voor de mensen zijn die het willen nabouwen staat hieronder de listing, zoals ik hem nu gebruik.

*************************************************************************************************************
/*FlowBench
 
  This program measures the difference in air pressure in the flow bench.
  The lower the pressure, the higher the value.
  The program displays the temperature, the air air pressur/10 and the flow.
 
  Gebaseerd op: BMP085 Extended Example Code
  Originele listing van https://www.sparkfun.com/tutorials/253
  by: Jim Lindblom
  SparkFun Electronics
  date: 1/18/11
  updated: 2/26/13
  license: CC BY-SA v3.0 - http://creativecommons.org/licenses/by-sa/3.0/
 
  Get pressure and temperature from the BMP085.
*/

#include <Wire.h>
#include <LiquidCrystal.h>
LiquidCrystal lcd(4, 5, 6, 7, 8, 9); // pins for RS, E, DB4, DB5, DB6, DB7

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 0;  // Oversampling Setting

// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5;

short temperature;
long pressure;
long basis;
long flow;

void setup()
{
  Serial.begin(9600);
  Wire.begin();
  bmp085Calibration();
  lcd.begin(16, 2);
  lcd.clear();
  temperature = bmp085GetTemperature(bmp085ReadUT());
  pressure = bmp085GetPressure(bmp085ReadUP());
  basis = pressure;
}
void loop()
{
  temperature = bmp085GetTemperature(bmp085ReadUT());
  pressure = bmp085GetPressure(bmp085ReadUP());
  flow = (basis - pressure)/10;

  lcd.setCursor(0, 0);
  lcd.print("Temp.");
  lcd.setCursor(7, 0);
  lcd.print(temperature*0.1,1);
  lcd.setCursor(10,0);
  lcd.setCursor(12,0);
  lcd.print("Flow");
  lcd.setCursor(0, 1);
  lcd.print("Pres.");
  lcd.setCursor(5, 1);
  lcd.print(pressure*0.01,1);
  lcd.setCursor(10,1);
  lcd.setCursor(12, 1);
  lcd.print(flow, DEC);
  delay(500);
  lcd.setCursor(12, 1);
  lcd.print("   ");
}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(unsigned int ut)
{
  long x1, x2;
 
  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  return ((b5 + 8)>>4); 
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;
 
  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
 
  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
 
  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;
   
  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;
 
  return p;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;
 
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();
 
  Wire.requestFrom(BMP085_ADDRESS, 1);
  while(!Wire.available())
    ;
   
  return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;
 
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();
 
  Wire.requestFrom(BMP085_ADDRESS, 2);
  while(Wire.available()<2)
    ;
  msb = Wire.read();
  lsb = Wire.read();
 
  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT()
{
  unsigned int ut;
 
  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x2E);
  Wire.endTransmission();
 
  // Wait at least 4.5ms
  delay(5);
 
  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;
 
  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x34 + (OSS<<6));
  Wire.endTransmission();
 
  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));
 
  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF6);
  Wire.endTransmission();
  Wire.requestFrom(BMP085_ADDRESS, 3);
 
  // Wait for data to become available
  while(Wire.available() < 3)
    ;
  msb = Wire.read();
  lsb = Wire.read();
  xlsb = Wire.read();
 
  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
 
  return up;
}